From d0d3d522ae1bae8fd61dc9c582c301bc53be4371 Mon Sep 17 00:00:00 2001
From: Olaf Lenz <olenz@icp.uni-stuttgart.de>
Date: Thu, 28 Aug 2014 15:22:34 +0100
Subject: [PATCH] Added new macro AX_CXX_VAR_PRETTYFUNC to determine the
 function name and fix some problems in AX_C_VAR_FUNC.

---
 m4/ax_c_var_func.m4         |  7 ++--
 m4/ax_cxx_var_prettyfunc.m4 | 92 +++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 96 insertions(+), 3 deletions(-)
 create mode 100644 m4/ax_cxx_var_prettyfunc.m4

diff --git a/m4/ax_c_var_func.m4 b/m4/ax_c_var_func.m4
index 0ad7d2b..161ba0d 100644
--- a/m4/ax_c_var_func.m4
+++ b/m4/ax_c_var_func.m4
@@ -59,8 +59,9 @@ AC_CACHE_CHECK(whether $CC recognizes __func__, ac_cv_c_var_func,
 AC_TRY_COMPILE(,
 [int main() {
 char *s = __func__;
-}],
-AC_DEFINE(HAVE_FUNC,,
-[Define if the C complier supports __func__]) ac_cv_c_var_func=yes,
+}], ac_cv_c_var_func=yes,
 ac_cv_c_var_func=no) )
+if test "x$ac_cv_c_var_func" = xyes; then
+   AC_DEFINE(HAVE_FUNC,,[Define if the C complier supports __func__])
+fi
 ])dnl
diff --git a/m4/ax_cxx_var_prettyfunc.m4 b/m4/ax_cxx_var_prettyfunc.m4
new file mode 100644
index 0000000..9afc525
--- /dev/null
+++ b/m4/ax_cxx_var_prettyfunc.m4
@@ -0,0 +1,92 @@
+# ===========================================================================
+#       http://www.gnu.org/software/autoconf-archive/ax_cxx_var_prettyfunc.html
+# ===========================================================================
+#
+# SYNPOSIS
+#
+#   AX_CXX_VAR_PRETTYFUNC
+#
+# DESCRIPTION
+#
+#   This function tries to determine the best C++ macro/identifier
+#   that contains the current function name. Depending on the
+#   compiler, this may be __PRETTY_FUNCTION__ (GCC), __FUNCSIG__
+#   (MSVC), __func__ (C++ standard), __FUNCTION__ (fallback).
+#
+#   The function will define HAVE_PRETTYFUNC if a macro exists,
+#   and define __PRETTYFUNC__ to the best possible macro.  When
+#   HAVE_PRETTYFUNC is not defined, __PRETTYFUNC__ will contain the
+#   constant string "<<unknown>>".
+#
+# LICENSE
+#
+#   Copyright (c) 2014 Olaf Lenz <olenz@icp.uni-stuttgart.de>
+#
+#   This program is free software: you can redistribute it and/or modify it
+#   under the terms of the GNU General Public License as published by the
+#   Free Software Foundation, either version 3 of the License, or (at your
+#   option) any later version.
+#
+#   This program is distributed in the hope that it will be useful, but
+#   WITHOUT ANY WARRANTY; without even the implied warranty of
+#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
+#   Public License for more details.
+#
+#   You should have received a copy of the GNU General Public License along
+#   with this program. If not, see <http://www.gnu.org/licenses/>.
+#
+#   As a special exception, the respective Autoconf Macro's copyright owner
+#   gives unlimited permission to copy, distribute and modify the configure
+#   scripts that are the output of Autoconf when processing the Macro. You
+#   need not follow the terms of the GNU General Public License when using
+#   or distributing such scripts, even though portions of the text of the
+#   Macro appear in them. The GNU General Public License (GPL) does govern
+#   all other use of the material that constitutes the Autoconf Macro.
+#
+#   This special exception to the GPL applies to versions of the Autoconf
+#   Macro released by the Autoconf Archive. When you make and distribute a
+#   modified version of the Autoconf Macro, you may extend this special
+#   exception to the GPL to apply to your modified version as well.
+
+#serial 1
+
+AC_DEFUN([AX_CXX_VAR_PRETTYFUNC],
+[
+# try to find best __FUNCTION__ variant
+
+AC_CACHE_CHECK([whether $CXX can get a pretty function name], ac_cv_cxx_var_prettyfunc, 
+    ac_cv_cxx_var_prettyfunc=no
+
+    AC_COMPILE_IFELSE(
+          [AC_LANG_PROGRAM(,[const char *s = __PRETTY_FUNCTION__])], 
+        [ ac_cv_cxx_var_prettyfunc=__PRETTY_FUNCTION__ ])
+
+    AS_IF([test "x$ac_cv_cxx_var_prettyfunc" = "xno"], [
+        AC_COMPILE_IFELSE(
+              [AC_LANG_PROGRAM(,[const char *s = __FUNCSIG__])], 
+            [ ac_cv_cxx_var_prettyfunc=__FUNCSIG__ ]) 
+    ])
+
+    AS_IF([test "x$ac_cv_cxx_var_prettyfunc" = "xno"], [
+        AC_COMPILE_IFELSE(
+        [AC_LANG_PROGRAM(,[const char *s = __func__])], 
+                       [ ac_cv_cxx_var_prettyfunc=__func__ ])
+    ])
+
+    AS_IF([test "x$ac_cv_cxx_var_prettyfunc" = "xno"], [
+        AC_COMPILE_IFELSE(
+        [AC_LANG_PROGRAM(,[const char *s = __FUNCTION__])], 
+                       [ ac_cv_cxx_var_prettyfunc=__FUNCTION__ ])
+    ])
+)
+
+
+AS_IF([test "x$ac_cv_cxx_var_prettyfunc" != "xno"], [
+    AC_DEFINE(HAVE_PRETTYFUNC,, [Whether __PRETTY_FUNCTION__ has a useful value.])
+    AC_DEFINE_UNQUOTED(__PRETTYFUNC__,$ac_cv_cxx_var_prettyfunc, 
+        [contains the function wherein the macro is called])
+],[
+    AC_DEFINE(__PRETTYFUNC__,"<<unknown>>")
+])
+
+])dnl
-- 
2.0.4

